COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	BEGIN "DATE"
C00005 ENDMK
C⊗;
BEGIN "DATE"
REQUIRE "PIXHDR.SAI[VIS,HPM]" SOURCE_FILE;
INTEGER ARRAY PC[0:10]; INTEGER CH;
STRING PROCEDURE DAYTIM;
   BEGIN
   INTEGER D,T;
   STRING PROCEDURE CVS2(INTEGER I); 
      RETURN((((I%10) MOD 10)+"0")&((I MOD 10)+"0"));
   D←CALL(0,"DATE"); T←CALL(0,"MSTIME"); SETFORMAT(0,7);
   RETURN((CASE ((D%31) MOD 12) OF
         ("January","February","March","April","May","June",
          "July","August","September","October","November","December"))&" "&
        CVS((D MOD 31)+1)&", "&CVS((D%31)%12+1964)&"    "&
        CVS2(T%(1000*60*60))&":"&
        CVS2((T%(1000*60)) MOD 60)&":"&CVS2((T%1000) MOD 60));
   END;

STRING PROCEDURE FILINF(INTEGER CHANNEL);
   BEGIN
   REQUIRE "{}{}" DELIMITERS;
   DEFINE POPJ(A,B)={'263000000000 LOR (A LSH 23) LOR B};
   DEFINE MTAPE(A,B)={'072000000000 LOR (A LSH 23) LOR B};
   INTEGER ARRAY MTP[0:3], RET[0:6], COD[0:2];  STRING FN,EXT,PPN,T; INTEGER I;
   MTP[0]←CVSIX("GODMOD"); MTP[1]←'14; MTP[2]←(-5 LSH 18) LOR LOCATION(RET[0]);
   COD[0]←MTAPE(CHANNEL,LOCATION(MTP[0])); COD[1]←COD[2]←POPJ('17,0);
   START_CODE PUSHJ '17,ACCESS(COD[0]); END;

   FN←CVXSTR(RET[1]); WHILE LENGTH(FN)>0 ∧ FN[∞ TO ∞]=" " DO FN←FN[1 TO ∞-1];
   EXT←CVXSTR(RET[2] LAND '777777000000);
                      WHILE LENGTH(EXT)>0 ∧ EXT[∞ TO ∞]=" " DO EXT←EXT[1 TO ∞-1];
   PPN←CVXSTR(RET[4]); T←PPN[1 TO 3]&","&PPN[4 TO 6];
   PPN←""; FOR I←1 STEP 1 UNTIL 7 DO IF T[I TO I]≠" " THEN PPN←PPN&T[I TO I];
   RETURN(FN&"."&EXT&"["&PPN&"]");
   END;

CH←OPNPFL("DSK:CART.PIC[PIC,HE]",PC[0]);
WHILE TRUE DO BEGIN INCHWL; PRINT(FILINF(CH),"    ",DAYTIM,'15&'12); END;

END "DATE";